nixos-config/home-manager/neovim/default.nix

{ config, lib, pkgs, user, theme, ... }:

let
  cmp-nvim-lsp-signature-help = pkgs.vimUtils.buildVimPlugin {
    name = "cmp-nvim-lsp-signature-help";
    version = "2022-07-21";
    src = pkgs.fetchFromGitHub {
      owner = "hrsh7th";
      repo = "cmp-nvim-lsp-signature-help";
      rev = "57c4db7d3a663bd31ef60c4b5ed32683301247e9";
      sha256 = "LKtMrxm9i+yoLYh1NuZsENSScB7MQZrjTFpD9wdpz1M=";
    };
    meta.homepage = "https://github.com/hrsh7th/cmp-nvim-lsp-signature-help";
  };

  lsp_lines-nvim = pkgs.vimUtils.buildVimPlugin {
    name = "lsp_lines.nvim";
    version = "2022-01-14";
    src = pkgs.fetchgit {
      url = "https://git.sr.ht/~whynothugo/lsp_lines.nvim";
      rev = "22ef87c6b2039aac069bfba1c5be5cd26c27b752";
      sha256 = "prhBuAM1jNxZz7F1SUlUda7dKJ/0eXq3Lw6XB9x7zR8=";
    };
    meta.homepage = "https://git.sr.ht/~whynothugo/lsp_lines.nvim";
  };
  pre-commit-nvim = pkgs.vimUtils.buildVimPlugin {
    name = "pre-commit.nvim";
    version = "2022-08-05";
    src = pkgs.fetchgit {
      url = "https://github.com/Ttibsi/pre-commit.nvim";
      rev = "4a608cef0f0a196fa39cdc60579eb9cf601d21c4";
      sha256 = "Y0biF/yrOX1YYztj8/u0n8zPN4YLGLSQL3vb9I3+3dE=";
    };
    meta.homepage = "https://github.com/Ttibsi/pre-commit.nvim";
  };
in
{
  home.packages = with pkgs; [
    xclip

    # language servers
    sumneko-lua-language-server
    rnix-lsp
    terraform-ls
    tflint
    rust-analyzer
    nodejs
    nodePackages.bash-language-server
    nodePackages.yaml-language-server
    nodePackages.prettier
    nodePackages.eslint_d
    nodePackages.typescript-language-server
    nodePackages.typescript
    nodePackages.dockerfile-language-server-nodejs
    nodePackages.vscode-html-languageserver-bin
    lldb
    vscode-extensions.vadimcn.vscode-lldb
  ];

  # symlink for a stable path 
  home.file.".vscode-extensions/vscode-lldb".source = pkgs.vscode-extensions.vadimcn.vscode-lldb;

  programs = {
    neovim = {
      enable = true;
      plugins = with pkgs.vimPlugins; [
        # theme
        nvim-solarized-lua

        delimitMate
        vim-bbye
        ansible-vim

        # session handling
        project-nvim
        auto-session

        nvim-treesitter
        markdown-preview-nvim # use({ "iamcco/markdown-preview.nvim", run = ":call mkdp#util#install()" })
        toggleterm-nvim
        nvim-notify
        comment-nvim
        lualine-nvim
        tabline-nvim
        indent-blankline-nvim
        plenary-nvim
        vim-illuminate
        registers-nvim
        pre-commit-nvim

        # git
        gitsigns-nvim
        vim-fugitive
        gv-vim
        git-blame-nvim

        # snippets
        friendly-snippets
        luasnip

        # auto-completion
        nvim-cmp
        cmp-nvim-lsp
        cmp-buffer
        cmp-path
        cmp-cmdline
        cmp-nvim-lua
        cmp_luasnip
        cmp-calc
        cmp-nvim-lsp-signature-help

        # telescope
        telescope-nvim
        telescope-fzf-native-nvim
        telescope-ui-select-nvim

        # LSP
        nvim-lspconfig
        lsp-status-nvim
        rust-tools-nvim
        lua-dev-nvim
        null-ls-nvim
        lsp_lines-nvim

        # debugging
        nvim-dap
        nvim-dap-ui
      ];

      extraConfig = ''
        lua << EOF
            vim.o.guifont = "DejaVu Sans Mono:h8"

            if vim.g.neovide then
                vim.g.neovide_fullscreen = true
                vim.g.neovide_cursor_animation_length = 0.01
                vim.g.neovide_cursor_trail_length = 0.01
            end

            ${builtins.readFile ./keymaps.lua }
            ${builtins.readFile ./options.lua }
            ${builtins.readFile ./treesitter.lua }
            ${builtins.readFile ./lspconfig.lua }
            ${builtins.readFile ./toggleterm.lua }
            ${builtins.readFile ./notify.lua }
            ${builtins.readFile ./comment.lua }
            ${builtins.readFile ./lualine.lua }
            ${builtins.readFile ./tabline.lua }
            ${builtins.readFile ./indent-blankline.lua }
            ${builtins.readFile ./gitsigns.lua }
            ${builtins.readFile ./luasnip.lua }
            ${builtins.readFile ./nvim-cmp.lua }
            ${builtins.readFile ./telescope.lua }

            ${builtins.readFile ./themes.lua }
            vim.opt.background = '${theme}'

            ${builtins.readFile ./project-nvim.lua }
            ${builtins.readFile ./dap.lua }

            vim.g.gitblame_date_format = "%r"

        EOF
      '';
    };
  };
}